players.db automatische backups?

Gib mal paar Info's unter was die DayZ Instanz läuft um die Möglichkeiten auszuloten.

Root Server / GameHoster?

CFTool am start?

bei Root Server kannst Du natürlich mit "Batch" Dateien Backups erstellen. Aber das Er die automatisch einspielt bei einem Crash... mmmh, schwer.

Dann kannst Du die einfach per Batch umkopieren und ein timestamp anhängen.

Das ganze in die "Aufgabenplanung" von Windows einrichten.

Hey ho,

Hab da mal was rausgesucht:

https://www.planet3dnow.de/vbu…mten-Zeitpunkten-kopieren

Sollte genau dein Problem beheben somit kopiert er immer zu einem gewissen Zeitpunkt die Dateien in einen Ordner

Wenn er das 4x am Tag macht, wird halt die Datei umbenannt. Aber denke das ist dann ned das Problem 1x die Woche löschen und gut is

Zitat von cj187

Einfach ist gut, hab davon NULL Ahnung

Kann Dir da was fertig machen

So,

hier mal ein paar Zeilen zum Sichern des ganzen DayZ Servers was wichtig ist:

backup.bat

Echo on

set SRV=Vanilla
set ZIP="C:\Program Files\7-Zip\7z.exe"
set OMGSRV=C:\Gamesrv\OmegaManager\servers\1
set SRCMISSION=%OMGSRV%\mpmissions
set SRCPROFIL=%OMGSRV%\profiles
set BCKDATE=%date:~-4%%date:~-7,2%%date:~-10,2%-%time:~-11,2%%time:~-8,2%
set BCKZIP=C:\Gamesrv\Backup\%SRV%
set BCK=C:\Gamesrv\Backup\%SRV%\%BCKDATE%

robocopy %SRCMISSION% %BCK% /R:3 /W:1 /E /XF *.log *.rpt *.adm
robocopy %SRCPROFIL% %BCK%\profiles /R:3 /W:1 /E /XF *.log *.rpt *.adm

%ZIP% a %BCKZIP%\%SRV%-%BCKDATE%.zip -r %BCK% -mx5

rmdir /S /Q %BCK%

Erklärung:

------------------------------------------------------------------------

Echo on /Sei gesprächig, kann später auf Echo off gesetzt werden.

set SRV=Vanilla /Servername, gut wenn man mehrere Server hat.

set ZIP="C:\Program Files\7-Zip\7z.exe" /Wo liegt 7Zip?

set OMGSRV=C:\Gamesrv\OmegaManager\servers\1 /Wo ist das DayZ-Server Verzeichnis?

set SRCMISSION=%OMGSRV%\mpmissions /Mission Ordner der zu sichern ist.

set SRCPROFIL=%OMGSRV%\profiles /Profil Ordner (Konfigs von MODs) der zu sichern ist.

set BCKDATE=%date:~-4%%date:~-7,2%%date:~-10,2%-%time:~-11,2%%time:~-8,2% /Datum u. Uhrzeit wird ermittelt.

set BCKZIP=C:\Gamesrv\Backup\%SRV% /Wohin soll gesichert werden inkl. Servername, siehe oben.

set BCK=C:\Gamesrv\Backup\%SRV%\%BCKDATE% /Erstellt Backup Verzeichnis inkl. Datum und Uhrzeit.

robocopy %SRCMISSION% %BCK% /R:3 /W:1 /E /XF *.log *.rpt *.adm /Der Copy Befehl für Mission ohne DayZ Logs

robocopy %SRCPROFIL% %BCK%\profiles /R:3 /W:1 /E /XF *.log *.rpt *.adm /Der Copy Befehl für Profiles ohne DayZ Logs

%ZIP% a %BCKZIP%\%SRV%-%BCKDATE%.zip -r %BCK% -mx5 /Um Platz zu sparen, das ganze per ZIP erstellen.

rmdir /S /Q %BCK% /Aufräumen, so das nur noch die ZIP bleibt.

------------------------------------------------------------------------

Warum ich das nicht direkt aus dem DayZ Server in eine Zip packe liegt daran das ich mit dieser Methode ein Bck während des Betriebes erstellen kann.

Beim Kopieren kann es öfter vorkommen das DayZ Server grade in die DB- Dateien schreibt. Somit können diese Dateien nicht gepackt werden... unvollständiges Backup.

Beim Kopiervorgang wird 3x versucht eine Datei in einem Abstand von 1 Sek. zu kopieren. Die Wahrscheinlichkeit das DayZ Server die Datei 3-4 Sekunden festhält ist gering. Somit kann ich dann die Kopie des Mission und Profil Ordner ohne Datei Verlust backen / sichern.

Ich habe hier nicht nur eine bestimmte Datei genommen zum sichern, denke das der eine oder andere Serverbetreiber alle wichtigen Sachen sichern möchte.

Das ganze mit "Aufgabenplanung" kombiniert, hat man lokal eine schnelle Sicherung. Wer Angst vor Datenverlust auf der Maschine hat, kann die Zip Dateien auf ein anderes Medium oder Server kopieren.

Eine Lösch- Routine ist hier nicht eingebaut, wer aber sowas einbauen möchte, dem kann ich "delage" empfehlen.

Gruß,

[moon]